Membuat Program Chatting (VB6)

1. Buatlah sebuah proyek bernama TCPServer.vbp.

2. Tambahkan sebuah form bernama frmChat dengan tampilan sebagai berikut.



3. Set property Enabled pada cmdDisconnect menjadi False.

4. Set property Locked pada txtChat menjadi True.

5. Ketikkan kode berikut pada tempatnya yang sesuai.

Private Const PortNumber = 4000

Private Sub cmdClose_Click()
Unload Me
End Sub


Private Sub cmdDisconnect_Click()
sck.Close

cmdDisconnect.Enabled = False
cmdListen.Enabled = True
End Sub

Private Sub cmdListen_Click()
sck.LocalPort = PortNumber
sck.Listen

cmdListen.Enabled = False
cmdDisconnect.Enabled = True
txtMsg.SetFocus
End Sub

Private Sub cmdSend_Click()
sck.SendData txtMsg.Text
End Sub

Private Sub Form_Load()
Show
cmdListen.SetFocus
End Sub

Private Sub sck_Close()
sck.Close
End Sub

Private Sub sck_ConnectionRequest(ByVal requestID As Long)
If sck.State <> sckClosed Then
sck.Close
End If
sck.Accept requestID
End Sub

Private Sub sck_DataArrival(ByVal bytesTotal As Long)
Dim sData As String

sck.GetData sData
txtChat.Text = txtChat.Text & sData & vbCrLf
End Sub

Private Sub sck_SendComplete()
txtMsg.Text = ""
End Sub

6. Bukalah jendela Microsoft Visual Basic yang baru, lalu buat sebuah proyek bernama TCPClient.vbp.

7. Tambahkan sebuah form bernama frmChat dengan tampilan sebagai berikut.



8. Set property Enabled pada cmdDisconnect menjadi False.

9. Set property Locked pada txtChat menjadi True.

10. Ketikkan kode berikut pada tempatnya yang sesuai.

Private Const RemoteHost = "Masagus" 'Nama server chat
Private Const PortNumber = 4000

Private Sub cmdClose_Click()
Unload Me
End Sub

Private Sub cmdConnect_Click()
sck.Connect RemoteHost, PortNumber
End Sub

Private Sub cmdDisconnect_Click()
sck.Close

cmdDisconnect.Enabled = False
cmdConnect.Enabled = True
End Sub

Private Sub cmdSend_Click()
sck.SendData txtMsg.Text
End Sub

Private Sub Form_Load()
Show
cmdConnect.SetFocus
End Sub

Private Sub sck_Close()
sck.Close
End Sub

Private Sub sck_Connect()
cmdConnect.Enabled = False
cmdDisconnect.Enabled = True
txtMsg.SetFocus
End Sub

Private Sub sck_DataArrival(ByVal bytesTotal As Long)
Dim sData As String

sck.GetData sData
txtChat.Text = txtChat.Text & sData & vbCrLf
End Sub

Private Sub sck_SendComplete()
txtMsg.Text = ""
End Sub

11. Jalankan TCPServer.vbp, kemudian tekan tombol Listen.

12. Jalankan TCPClient.vbp, kemudian tekan tombol Connect.

13. Cobalah untuk saling berkirim data.

Mendapatkan Nama dan Alamat IP Komputer (VB6)

1. Buatlah sebuah proyek dengan nama LocalIP.vbp.

2. Buat sebuah form bernama frmLocalIP dengan tampilan sebagai berikut.



3. Set properties-nya menjadi sebagai berikut.

Obyek	Property	Nilai
txtHost	BackColor	&H00C0C0C0
txtHost	Locked	True
txtIP	BackColor	&H00C0C0C0
txtIP	Locked	True

4. Tambahkan kode seperti di bawah ini.

Private Sub cmdClose_Click()
Unload Me
End Sub

Private Sub cmdResolve_Click()
txtHost.Text = sck.LocalHostName
txtIP.Text = sck.LocalIP
End Sub

Private Sub Form_Load()
Show
cmdResolve.SetFocus
End Sub

5. Jalankan program. Tekan tombol Resolve, maka nama komputer dan alamat IP-nya akan tertera.

Perintah-Perintah Umum Analisis Jaringan dan Internet

Pada tahun 1972, lembaga riset Departemen Pertahanan Amerika Serikat, DARPA (Defense Advance Research Project Agency) telah berhasil membangun jaringan komunikasi data antar komputer pertama di dunia yang kemudian diberi nama ARPANET. Sejak saat itu, aplikasi-aplikasi yang digunakan untuk jaringan dan internet mulai dibuat dan diminati. Aplikasi internet yang pertama kali ditemukan adalah FTP, menyusul kemudian email dan telnet. Dunia pemrograman jarngan dan internet menjadi semakin ramai sekitar tahun 1990-an sampai sekarang seiring dengan ramainya penggunaan internet.

Jaringan TCP/IP termasuk internet pertama kali dibangun di atas platform UNIX. Pemrograman jaringan di dalam sistem operasi UNIX menggunakan standar pustaka yang disebut dengan Socket. Microsoft Windows sebagai sebuah sistem operasi yang mendukung protocol TCP/IP pun kemudian menggunakan standar ini. Dalam Windows, implementasi socket ini diberi nama WinSock. Tanpa socket, sebuah sistem operasi tidak akan dapat mengimplementasikan protocol TCP/IP. Penguasaan akan WinSock menjadi pintu gerbang bagi seorang programmer jaringan di lingkungan sistem operasi Windows.

Perintah-perintah di bawah ini berguna untuk menganalisa dan memperbaiki masalah-masalah yang berhubungan dengan jaringan dan internet. Beberapa dari perintah-perintah tersebut hanya dapat bekerja pada sebuah server dengan sistem operasi Microsoft Windows.

Perintah	Kegunaan	Keterangan
arp	Melihat ARP (Address Resolution Protocol) cache pada interface komputer lokal.
hostname	Menampilkan nama host komputer lokal.	Hanya pada server Windows.
ipconfig	Menampilkan konfigurasi jaringan TCP/IP dan DHCP, mengalokasikan, menampilkan dan mendaftarkan nama DNS.
nbtstat	Mengecek keadaan NetBIOS yang dipakai dalam koneksi jaringan TCP/IP, mengupdate nama NetBIOS cache dan menentukan registrasi nama dan scope ID.
netstat	Menampilkan statistik koneksi pada jaringan TCP/IP
nslookup	Mengecek record, domain host aliases, domain host services dan informasi sistem operasi dengan proses query DNS.	Hanya pada server Windows.
ping	Mengirim ICMP Echo Requests untuk mengecek apakah konfigurasi TCP/IP sudah benar dan sistem TCP/IP pada remote host ada atau tidak.
tracert	Trace path jalur penyampaian data kepada remote host.
pathping	Trace path pada remote host dan melaporkan paket yang hilang pada masing-masing router sepanjang jalur pengiriman data.	Hanya pada server Windows.
route	Menampilkan tabel routing IP serta menambah atau menghapus rute IP.

Sintaks lengkap masing-masing perintah dapat dilihat dengan cara mengetik: /help.